#!/mclab/imc/sun4/rexx -x

httpdir="/usr/local/etc/httpd/htdocs/oucl/users/ian.collier"
/* This is the root directory of my WWW pages */

outdir=httpdir || '/Programs'    /* directory in which all files reside */
outfile=outdir || '/index.html'  /* the file which will be output */
address command 'rm' outfile

/* What follows is normal HTML, but with the extra tags <ls>...</ls>
   and <date> (each of which must be on a line on its own).  Each line
   after the "call print" will be printed out. */

call print /*
<title>Miscellaneous programs</title>
<h1>Miscellaneous Programs</h1>

Welcome to my program page.  This is where I get to distribute any software
that I think deserves some publicity but which isn't significant enough to
be put on an ftp site or posted to a newsgroup.
 <p>
<date>
 <p>
As this is only an example program, I haven't included the whole
index text.  However, I have included a list of files.
<ls>
makeindex1        this program
makeindex2        a related program
</ls>
Following the last line of text you should place the end-comment
delimiter on a line of its own.
*/
exit
print:
parse value date(s) with yyyy +4 +2 dd
do i=sigl+1 to sourceline()
   l=sourceline(i)
   if l='*/' then leave
   if l='<date>' then call lineout outfile, ,
                      "Last updated:" dd+0 date('m') yyyy+0'.'
   else if l\='<ls>' then call lineout outfile,l
   else do 
      /* Treat each line up to </ls> as a filename plus description. */
      /* First output the header lines */
      call lineout outfile,'<pre>'
      call lineout outfile,left('Name',18) '   Size  Last Updated  Description'
      call lineout outfile,''
      do forever
         i=i+1
         l=sourceline(i)
         if l='</ls>' then leave
         parse var l file desc
         parse value 'ls'('-lL',outdir || '/' || file) with,
            perm linx usr size mon date time name
         call lineout outfile,'<a href="' || file || '">' || file || '</a>' ||,
            copies(' ',18-length(file)) right(size,7) || '  ' ||,
            mon right(date,2) right(time,5) || '  ' || strip(desc)
      end
      call lineout outfile,'</pre>'
   end
end
return